group = "io.openim.flutter_openim_sdk"
version = "1.0"

buildscript {
    repositories {
        google()
        mavenCentral()
    }

    dependencies {
        classpath("com.android.tools.build:gradle:8.7.3")
    }
}

rootProject.allprojects {
    repositories {
        google()
        mavenCentral()
    }
}

apply plugin: "com.android.library"

def localCoreRepo = file("repo")
def localCoreVersion = "3.8.3-patch10"
def localCorePom = file("repo/io/openim/core-sdk/${localCoreVersion}/core-sdk-${localCoreVersion}.pom")

android {
    namespace = "io.openim.flutter_openim_sdk"

    compileSdk = 35

    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_11
        targetCompatibility = JavaVersion.VERSION_11
    }

    defaultConfig {
        minSdk = 21
    }

    testOptions {
        unitTests.all {
            testLogging {
               events "passed", "skipped", "failed", "standardOut", "standardError"
               outputs.upToDateWhen {false}
               showStandardStreams = true
            }
        }
    }
}

repositories {
    google()
    mavenCentral()
    if (localCorePom.exists()) {
        maven {
            url uri(localCoreRepo)
        }
    }
}

dependencies {
    if (localCorePom.exists()) {
        implementation "io.openim:core-sdk:${localCoreVersion}"
    } else {
        implementation "io.openim:core-sdk:${localCoreVersion}@aar"
    }
    testImplementation("junit:junit:4.13.2")
    testImplementation("org.mockito:mockito-core:5.0.0")
}